!BAT
# IMPORTANT: This file MUST begin with !BAT
# For all settings, see \_ISO\Sample_MyE2B.cfg
#
# HELP
#   # symbols comment out a line - do not remove!
#   ### means you can uncomment and use ### lines - they should contain a set command
#
#   e.g.
#         # Auto menu     - this should not be uncommented - do not delete the # symbol
#       ###set DEFM_MNU=0 - this can be uncommented and changed by the user


#if you really want to use a gfxmenu then specify the file here
#gfxmenu limitations include (if error goes to text mode, no timeout or default option, number of isos cannot be displayed)
#Place your gfxmenu file in the /_ISO folder
###set GFX=message
set GFX=

#Turn of alphabetical sorting of menus (speeds up enumeration of menus)
###set NOSORT=1

# Dont show file extensions in menu
set EXTOFF=1

#no menu password
set pwd=

#don't show arrow on left of menu
write 0x8308 0 > nul

# don't number menu items
set AUTONUM=0

# Make the F1 key show the Help Menu from any menu (uncomment 3 lines below) - you can put your own help file in \_ISO\F1.cfg
if exist /_ISO/F1.cfg   ()/%grub%/hotkey [F1] "configfile /_ISO/F1.cfg" > nul && goto :f1skp
if exist /%grub%/%LANG%/F1.cfg ()/%grub%/hotkey [F1] "configfile /%grub%/%LANG%/F1.cfg" > nul && goto :f1skp
if exist /%grub%/ENG/F1.cfg ()/%grub%/hotkey [F1] "configfile /%grub%/ENG/F1.cfg" > nul
:f1skp

# Use this line to display the background image as early as possible with a few progress messages
call Fn.70 3 ;; set redir=> nul 


# ------------ HEADING AND FOOTER TEXT COLOUR ---------
# HCOLOUR sets the colour of the HEADING and FOOTER TEXT text 
# HCOLOUR=ABCD specifies the text colour  [BLINK|BRIGHT|BACKGROUND|FOREGROUND]
# A=0/1 1 = BLINK text (does not work under VM)
# B=0/1 1 = BRIGHT colour for foreground text
# C=0-7 = BACKGROUND colour - transparent if graphics mode so has no effect!
# D=0-7 = FOREGROUND menu text colour
# Colours parameters are: 0=black/grey 1=dark blue, 2=green, 3=aqua, 4=dark red, 5=pink, 6=yellow/brown, 7=grey/white.
# e.g. 0133 is non-blinking bright aqua text (on a dark aqua background if not in graphics mode)

set HCOLOUR=0034
set FCOLOUR=0133
#                  --------- MENU HEADINGS -----
#
# Headings must be between two \x20 and between 58 and 78 characters long - but not more than 78 or will get line wrapover if in 640x480 mode
#                          1         2         3         4         5         6         7         8
#              \x202345678901234567890123456789012345678901234567890123456789012345678901234567890\x20
#                                                                           XXXXXXXXXXXXXXXXXXX  <- text must end in this area!
#
set    HEADING=\x20   EASY2BOOT V1 - MAIN MENU  (%VER%)                         \x20

# use \x20 for no text at the bottom of the first menu - e.g. set HELPTEXT=\x20
set HELPTEXT=E2B Jolene Theme Demo\n echo -n -P:%HBTM% $[%FCOLOUR%] HDD0 [F7]   Back [F8]   Reboot [F9]   Power Off [F10]    www.easy2boot.com

#  ----- GRAPHICS MODE AND WALLPAPER -----

# set graphics mode - use 640, or 800 or 1024 - or specify full mode - e.g. 800 600 24
# 640 and 800 is supported by the default background bitmap
set GMODE=800
###set MYWBMP=/_ISO/mybackground.bmp
set MYWBMPGZ=/_ISO/docs/Templates/jolene/jolene800.bmp.gz

# -------- MENU COLOURS -------

# Colour pairs are Text/Background - i.e cyan/blue = cyan text on blue background
# Use black if a transparent background is required for menu highlight background - e.g. highlight=red/black
# Valid colours are: black, blue, green, cyan, red, magenta, brown, light-gray, dark-gray, light-blue, light-green, light-cyan, light-red, light-magenta, yellow and white.
#  normal    = normal menu text
#  highlight = highlighted menu text when a menu entry is selected
#  helptext  = the colour of the title help text shown just below the menu box
#  standard  = the console background and text colours (e.g. when listing files)
#  border    = the colour of the border of the menu box

color normal=blue/black highlight=light-red/black helptext=red/black standard=light-blue/black border=light-gray/black

# You can also set a full colour value 24-bit as 0xRRGGBB, the value must be larger than 0xFF to work correctly however
# The background colour will be set to black (transparent in graphics mode menus)
# See http://www.rapidtables.com/web/color/RGB_Color.htm
# Red=0xFF0000   Green=0x00FF00   Blue=0x0100FF  (must be over FF so add 01 to red!), Yellow=0xFFFF00, White=0xffffff, Brown=0x994c00
### color border=0xFF0000
### color normal=0x777700
### color highlight=0xffffff

# ----- MENU POSITION ---

# If USING 640 or 800 x-resolution - the settings below will change automatically
# wordspacing linespacing borderwidth tophelp numberofitemsinmenu topstart menuwidth rightstartposofmenu
# tophelp=topstart+noitems for menuhelp text just under menu box
set wdspace=0
set lnspace=0
set topstart=4
set rstart=3
set noitems=18
set menuw=78
set bdwidth=0
set tophelp=22

# --- AUTOMATICALLY change border parameters if 800x600 set -----

if "%GMODE%"=="800" set noitems=24
if "%GMODE%"=="800" set tophelp=27

# -- FOOTER HELP TEXT ---
#Bottom Easy2Boot Help text position YYXX
set HBTM=2800
# if in 800 hres set, put bottom help text lower down - 36 lines if 800 mode
if "%GMODE%"=="800" set HBTM=3300

#   ---- PASSWORD PROTECTION -----
#Uncomment the line below to set a password of 'easy2boot' to stop users editing the menus accidentally
#If you want to edit the menus, press p and then enter the password (you can use an unencypted password like this: 'set pwd=fred'
#set pwd=--md5 $1$1$okAQ3AJUdhqf3TVrwKvJP1
set pwd=easy2boot

# ---- KEYBOARD TYPE -----
#set which keyboard you are using - see the KBD_xxxx.g4b files in the grub folder
#KBD_AZERTY.g4b
#KBD_FRENCH.g4b
#KBD_GERMAN.g4b
#KBD_ITALIANO.g4b
#KBD_JAPAN_106.g4b
#KBD_QWERTY_UK.g4b
#KBD_QWERTZ.g4b
#KBD_SPANISH.G4B

set KBD=KBD_QWERTY_UK.g4b

# ---- MENU ORDER -----
# if MNUFIRST=1 then the .mnu files in the MainMenu folder will be listed before the .ISO files
# if MNUFIRST=1 DIRECT BOOT, SPECIAL BOOT, INSTALL WINDOWS, Power Off, Boot to 2st HDD will be listed BEFORE an ISO files
# if MNUFIRST=1 and .ISO files in MainMenu folder will be listed at the end of the Main Menu
# if MNUFIRST is commented out, .ISO files in the MainMenu folder will be listed at the beginning of the Main Menu
set MNUFIRST=1

#  ----- REDUCE MEMORY USAGE -----
#This disables the loading of batch file modules into memory for faster execution (so MOD=1 may slower)
#if too many files or variables cause grub4dos to crash then uncomment the line
###set MOD=1


# SUPPRESS FILE ENUMERATION MESSAGES from AD2FMM.g4b, AUTOMN.g4b, etc.
set redir=> nul

# SUPPRESS STARTUP MENU.Lst messages
###set redirp=> nul



